plugins {
    id 'org.jetbrains.kotlin.jvm' version '1.3.61'
    id 'java'
    id 'idea'
}


repositories {
    mavenCentral()
    jcenter()
}

subprojects {
    // Hack to allow defining global dependencies
    apply plugin: 'java'
    apply plugin: 'org.jetbrains.kotlin.jvm'

    group = 'wf.servitor'
    version = '1.0-SNAPSHOT'

    def versions = project.ext.versions = [
            kotlin            : '1.3.61',
            jackson           : '2.9.10',
            joda_time         : '2.10.5',
            koin              : '2.0.1',
            kotlinx_coroutines: '1.3.2',
            jexl              : '3.1',
            junit             : '5.5.2',
            activemq          : '2.11.0',
    ]

    repositories {
        mavenCentral()
        jcenter()
    }

    dependencies {
        // Kotlin
        implementation "org.jetbrains.kotlin:kotlin-stdlib-jdk8:${versions.kotlin}"

        // Kotlin tests
        implementation "org.jetbrains.kotlin:kotlin-test:${versions.kotlin}"
        implementation "org.jetbrains.kotlin:kotlin-test-junit5:${versions.kotlin}"

        // Kotlin Coroutines
        implementation "org.jetbrains.kotlinx:kotlinx-coroutines-core:${versions.kotlinx_coroutines}"

        // Koin
        implementation "org.koin:koin-core:${versions.koin}"

        // ActiveMQ
        implementation "org.apache.activemq:artemis-core-client:${versions.activemq}"

        // JUnit
        testImplementation "org.junit.jupiter:junit-jupiter:${versions.junit}"

        if (project.name != 'common') {
            implementation project(':common')
        }
    }

    compileKotlin {
        kotlinOptions.jvmTarget = "12"
    }

    compileTestKotlin {
        kotlinOptions.jvmTarget = "12"
    }

    sourceCompatibility = 12
    targetCompatibility = 12

    test {
        useJUnitPlatform()
        testLogging {
            events "passed", "skipped", "failed"
        }
    }
}